Torus in Asymptote

A torus[1] is a great example of a parametric equation[2] with two parameters. We can think of one parameter $\alpha$ that revolves around the Z-axis to form a large circle; and another parameter $\beta$ that sweeps small circles to form the torus.

Fig 1: Parametric torus
$\copyright$ CC 2.5 - David Burke

The concept of these two circles can be seen in figure 1. Note that $\alpha$ goes is the direction of the blue arrow and $\beta$ 's sweep is shown by the red arrow.

Asymptote[3] is an application that allows us to create technical drawings using a programming language. It is a very powerful application - what we show here only touches the surface of what is possible to do with it. We can play with it using the Asymptote online sandbox hosted by the University of Alberta, or installing the software. If you have Latex installed, you might have the program on your workstation already.

This article has the following straight forward challenge:

Use Asymptote to draw a torus that is defined as a parametric equation.

Math groundwork #

First off, let's get the mathematics down. We use the notation $[x,y,z]$ as a row vector to denote a vector or a point in three dimensional Cartesian space[4].

For our blue circle, centered around the origin $[0,0,0]$ , we get this parametric equation:
$f_{a} (r, α) = r_{1} [cos α, sin α, 0] (1)$
Where

$r_1$ is the radius of the big circle
$\alpha \in [0;2\pi]$ is the parameter

Note that the radius $r$ does not exactly trace blue line in figure 1. Our large circle traces through the centers of the small circles.

We can think of $f_a$ as a generator of vectors. For each vector $v$ we need to draw the smaller circle that is described by $\beta$ .

Consider $v_u = v / |v|$ as the unit vector of $v$ . The small circle is drawn for this unit vector. It is a circle where the 'right' direction is $v_u$ and the 'up' direction is the $y$ axis:

$f_{v} (r_{2}, v_{u}, β) = r_{2} v_{u} cos β + r_{2} sin β [0, 0, 1] = r_{2} v_{u} cos β + r_{2} [0, 0, sin β]$
Where

$r_2$ is the radius of the small circle
$v_u$ is a unit vector
$\beta$ is the parameter

We have to draw this circle for each $v$ , so for the small circles we get this equation:
$f_{b} (v, r_{2}, β) = v + f_{v} (r_{2}, \frac{v}{∣ v ∣}, β) = v + r_{2} \frac{v}{∣ v ∣} cos β + r_{2} [0, 0, sin β] = v (1 + \frac{r _{2} cos β}{∣ v ∣}) + r_{2} [0, 0, sin β] (2)$

Where

$r_2$ is that radius of the small circle
$v$ is the vector from the bigger circle, with $|v|$ denoting the length of that vector.
$\beta \in [0;2\pi]$ is the parameter

Note that the length of $v$ is always the radius of the large circle ( $|v| = r_1$ ). So we can combine equation 1 and 2:
$f (r_{1}, r_{2}, α, β) = f_{b} (\cdot, r_{2}, β) \circ f_{a} (r_{1}, α) = f_{a} (r_{1}, α) (1 + \frac{r _{2} cos β}{r _{1}}) + r_{2} [0, 0, sin β] = r_{1} [cos α, sin α, 0] (1 + \frac{r _{2} cos β}{r _{1}}) + r_{2} [0, 0, sin β] = [cos α, sin α, 0] (r_{1} + r_{2} cos β) + r_{2} [0, 0, sin β] (3)$
Where

$r_1$ is the radius of the large circle
$r_2$ is the radius of the small circle
$\alpha \in [0;2\pi]$ is a parameter
$\beta \in [0;2\pi]$ is a parameter

We leave this function in the vector form because Asymptote can work with vectors. This function $f$ is the function of our torus in parametric form.

Asymptote basics #

Asymptote uses the data type called triple to keep three dimensional coordinates.

In program 1 below, we declare a triple and print its length.

triple p = (2,3,sqrt(12));
write("p=",p);
write("length of p=",length(p));

Program 1: Asymptote triple

In the next program, we show how to declare and invoke a function:

triple fun(triple v) {
  return v*2;
}
triple p = (2,3,4);
write("fun(p)=",fun(p));

Program 2: Asymptote function

Asymptote torus #

The program below draws the torus. (If you try it online here, you get an interactive 3d drawing.)

import graph3;
real r_1 = 2;
real r_2 = 0.25;

size(10cm,0);
currentprojection=perspective(1,2,1);

triple f(real r_1,real r_2, real alpha, real beta) {
  return (cos(alpha),sin(alpha),0)*(r_1 + r_2*cos(beta)) 
	  + r_2*(0,0,sin(beta));
}

triple mapper(pair t) {
  return f(r_1,r_2,t.x,t.y);
}

surface s=surface(mapper,(0,0),(2pi,2pi),16,16,Spline);
draw(s,rgb(0.6,0.6,0.7));

Program 3: Torus drawing

You can see the image produced by this program in figure 3 below.

Fig 3: Image produced by Asymptote

We need the mapper function to go from a pair to a call to the function $f$ . This mapping not absolutely required, but it is nice to see our function $f$ defined in equation 3 directly coded into the Asymptote language.

Conclusion #

We have seen here how to get a parametric function of a torus and also how to draw that in the Asymptote application. The end result is a very small program.

References #

Next: A parametric shell surface
Previous: A 3-D seashell spiral